export function to focus window if possible

[theSoberSobber]

when using the ahk v2 script it doesn't focus the window in front when it has already switched to a workspace, this is incredibly annoying and I was hoping that there could be a function that could be used to focus already stored window ID or something that had the focus last time. Thanks!

[Ciantic]

Yes, I've noticed this too before. But the purpose of this library is generally not to store data, this is the implementation detail of the AHK script you are making.

You can write it in a script: store the old focused window and restore it on OnChangeDesktop.

[theSoberSobber]

I see. I can def store the last focused in an array or something such that the indices match the desktop number and a[idx] = window id. But how do I focus the window? Like is there a function i call to focus a window with a window ID? How do I get the window ID in the first place? Sorry very new to ahk and dlls in general, don't know much other than js and py that's why confused.

[theSoberSobber]

I'm sorry, I think this works https://www.autohotkey.com/docs/v2/lib/WinActivate.htm I am just not sure on how to make autohotkey preserve that data now, like how do i write to a file, if I do, can the ahk lang allow me to split the input read as a string to an array on a comma delimeter if i wanna store like that etc.? sorry for bothering can you please provide some level of guidance? I am very new to AHK.

[Ciantic]

You don't need to write to a file, you can use an dictionary.

activeWindowByDesktop[current] := activeHwnd

On left side of dictionary you have current desktop number, on right side you have active window handle.

I don't have time to test this myself at the moment. But I had this same setup earlier.

I'll paste some relevant snippets:

WinGet, activeHwnd, ID, A
current := DllCall(GetCurrentDesktopNumberProc, UInt)
isPinned := DllCall(IsPinnedWindowProc, UInt, activeHwnd)
if (isPinned == 0) {
    activeWindowByDesktop[current] := activeHwnd
}

These are from AHK1 days, so you might need to change them.

Idea is to store it before you change desktop and restore it from the dictionary OnChangeDesktop

[Ciantic]

Btw, the reason my example script doesn't do that at the moment is because it should work without these tricks.

But Windows is flaky when changing desktops, sometimes it remembers the focus and sometimes it doesn't.

[theSoberSobber]

hey! thanks for the reply! and sorry for the late reply, got busy somewhere and couldn't even think about this.
I did try what you suggested but I am having trouble declaring the activeWindowByDesktop dictionary as when I declare one by doing activeWindowByDesktop={} and then try to declare key value pairs in it, it errors to saying there is no attribute object on the dictionary.
Also I don't know how would one go about focusing the window using it's hwnd (WinActive seems to be taking much more than that) and I don't know how to setup the before change desktop hook :((

Could you paste the whole part from your ahk 1 setup? I bet it won't have many changes, Sorry for troubling you again!

[theSoberSobber]

Hey for anyone encountering this issue, I was having a tough time using AHK and navigating the sparse documentation, so I ended up making a simple hotkeydaemon to use this dll here.

[LiaoliaoLiu]

Spent 1 hour learning how to write ahk 2 script with chatGPT. Here is an ugly (but working) version based on @Ciantic's suggestions:

nixos in /mnt/c/Users/liuli/Desktop/New folder
❯ diff -u template.ahk modified.ahk
--- template.ahk        2025-03-07 00:10:28.973360300 -0800
+++ modified.ahk        2025-03-07 00:10:48.555233100 -0800
@@ -60,9 +60,53 @@
     return
 }

+activeWindowByDesktop := Map()
+
+GetCurrentDesktopNumber() {
+    global GetCurrentDesktopNumberProc
+    return DllCall(GetCurrentDesktopNumberProc, "UInt")
+}
+
+; Store the current active window handle
+StoreCurrentWindow() {
+    global activeWindowByDesktop
+    current := GetCurrentDesktopNumber()
+    try {
+        activeHwnd := WinGetID("A")
+    } catch {
+        ; If no active window, exit the function
+        return
+    }
+
+    ; Only store if the window exists and isn't pinned
+    if (activeHwnd && WinExist("ahk_id " activeHwnd)) {
+        isPinned := DllCall(IsPinnedWindowProc, "UInt", activeHwnd)
+        if (isPinned == 0) {
+            activeWindowByDesktop[current] := activeHwnd
+        }
+    }
+}
+
+; Restore the window on the specified desktop
+RestoreWindow(num) {
+    global activeWindowByDesktop
+    if (activeWindowByDesktop.Has(num)) {
+        hwnd := activeWindowByDesktop[num]
+        if (WinExist("ahk_id " hwnd)) {
+            WinActivate("ahk_id " hwnd)
+        } else {
+            ; Window no longer exists, remove it from our tracking
+            activeWindowByDesktop.Delete(num)
+        }
+    }
+}
+
+
 GoToDesktopNumber(num) {
-    global GoToDesktopNumberProc
+    global GoToDesktopNumberProc, activeWindowByDesktop
+    StoreCurrentWindow()
     DllCall(GoToDesktopNumberProc, "Int", num, "Int")
+    RestoreWindow(num)
     return
 }
 MoveOrGotoDesktopNumber(num) {
@@ -100,6 +144,89 @@
     return ran
 }

+; Initialize activeWindowByDesktop with existing windows
+InitializeWindowsByDesktop() {
+    global activeWindowByDesktop, IsPinnedWindowProc
+
+    try {
+        ; Get a list of all windows
+        windowList := WinGetList()
+        desktopCount := GetDesktopCount()
+        currentDesktop := GetCurrentDesktopNumber()
+        Loop desktopCount {
+            desktopNum := A_Index - 1
+            DllCall(GoToDesktopNumberProc, "Int", desktopNum, "Int")
+            desktopWindows := Array()
+            for hwnd in windowList {
+                try {
+                    ; Skip if window no longer exists
+                    if (!WinExist("ahk_id " hwnd)) {
+                        continue
+                    }
+                    ; Skip minimized windows and pinned windows
+                    if (WinGetMinMax("ahk_id " hwnd) == -1) {
+                        continue
+                    }
+                    isPinned := DllCall(IsPinnedWindowProc, "UInt", hwnd)
+                    if (isPinned) {
+                        continue
+                    }
+                    ; Check if window is on current desktop
+                    if (DllCall(IsWindowOnCurrentVirtualDesktopProc, "Ptr", hwnd, "Int")) {
+                        ; Only consider visible, non-minimized windows
+                        if (WinGetStyle("ahk_id " hwnd) & 0x10000000) { ; WS_VISIBLE
+                            desktopWindows.Push(hwnd)
+                        }
+                    }
+                } catch as err {
+                    OutputDebug("Error processing window handle " hwnd ": " err.Message)
+                    continue
+                }
+            }
+            ; Find the most recently used window on this desktop
+            if (desktopWindows.Length > 0) {
+                try {
+                    ; Store the first window we found as a fallback
+                    activeWindowByDesktop[desktopNum] := desktopWindows[1]
+                    ; Try to get the window with focus (if any)
+                    for hwnd in desktopWindows {
+                        try {
+                            if (WinExist("ahk_id " hwnd) && WinGetExStyle("ahk_id " hwnd) & 0x8) { ; WS_EX_TOPMOST
+                                activeWindowByDesktop[desktopNum] := hwnd
+                                break
+                            }
+                        } catch as err {
+                            OutputDebug("Error checking topmost status: " err.Message)
+                            continue
+                        }
+                    }
+                } catch as err {
+                    OutputDebug("Error assigning window to desktop " desktopNum ": " err.Message)
+                }
+            }
+        }
+
+        ; Return to the original desktop
+        DllCall(GoToDesktopNumberProc, "Int", currentDesktop, "Int")
+
+        ; Debug output
+        for desktopNum, hwnd in activeWindowByDesktop {
+            try {
+                if (hwnd && WinExist("ahk_id " hwnd)) {
+                    title := WinGetTitle("ahk_id " hwnd)
+                    OutputDebug("Desktop " desktopNum ": " title " (hwnd: " hwnd ")")
+                } else {
+                    OutputDebug("Desktop " desktopNum ": No valid window stored")
+                }
+            } catch as err {
+                OutputDebug("Error getting window title: " err.Message)
+            }
+        }
+    } catch as err {
+        OutputDebug("Error during initialization: " err.Message)
+    }
+}
+InitializeWindowsByDesktop()
 ; SetDesktopName(0, "It works! 🐱")

 DllCall(RegisterPostMessageHookProc, "Ptr", A_ScriptHwnd, "Int", 0x1400 + 30, "Int")

[mid-kid]

Is it really not possible to focus the topmost window after switching? How does windows do this, then?

[Dovias]

Welp this works, but is hacky as hell. Are we sure this DLL really exports a high level enough undocumented API function which switches the desktop? The fact that this exported function doesnt produce any animations, neither focuses current window as it does with WIN+CTRL hotkeys leads me to suspect otherwise?

[Geodesic0]

Also following this thread. The switcher is otherwise perfect. Much gratitude, Ciantic

[theSoberSobber]

Is it really not possible to focus the topmost window after switching? How does windows do this, then?

Hey @mid-kid, check this out, I've tried to implement that as much as possible, hope it helps :))

[structnull]

Is it really not possible to focus the topmost window after switching? How does windows do this, then?

Found This : pmb6tz/windows-desktop-switcher#77 (comment)