Drag scroll bar in a medium-sized string is too slow.

[tinchodias]

Evaluate this script, then drag the scroll bar a few seconds.

editor := AlbEditorElement new.
editor text: (String loremIpsum: 50000) asRopedText.

vscrollBar := BlVerticalScrollbarElement new.
vscrollBar constraintsDo: [ :c |
	c ignoreByLayout.
	c ignored horizontal alignRight ].
vscrollBar attachTo: editor infinite.

vscrollBar thumb
	addEventHandlerOn: BlDragStartEvent do: [ :evt |
		profiler := AndreasSystemProfiler new.
		profiler startProfiling ];
	addEventHandlerOn: BlDragEndEvent do: [ :evt |
		profiler stopProfiling.
		profiler doReport ].

space := BlSpace new.
space root addChild: editor.
space root addChild: vscrollBar.
space extent: 300@900.
space show.

This shows a profiler report in text, from where I focus on:

[[[                                                  68.4 (3,493)  AlbTextEditorLineSegmentHolder  pieceForElemen...ent:ifAbsent:
[[[                                                    67.4 (3,441)  AlbTextEditorLineSegmentPieceMap  pieceForElemen...ent:ifAbsent:
[[[                                                      56.800000000000004 (2,900)  Dictionary  associations
[[[                                                        |56.800000000000004 (2,900)  Array class  new:streamContents:
[[[                                                        |  43.5 (2,221)  WriteStream class [PositionableStream class]  on:
[[[                                                        |  12.5 (638)  Dictionary  associations
[[[                                                        |    12.4 (633)  Dictionary  associationsDo:
[[[                                                        |      11.8 (603)  Array [SequenceableCollection]  do:
[[[                                                        |        7.800000000000001 (398)  Dictionary  associationsDo:

68% of time is spent searching on the values of dictionaries (i.e. not searching a key, a scenario where Dictionaries perform better... it's searching among the values).

Even worse, all this calculation is part of answering AlbPrimarySelectionElement>>#selectionRectangles. When I logged the result, it was always an empty array!!!

So, 68% of time while dragging the scroll bar it is used in obtaining again and again an empty collection.

[tinchodias]

The editorElement has a text element for each word in the lorem ipsum. There is nothing selected but each time scroll bar thumb moves 1 pixel, every word is iterated again:

AlbPrimarySelectionElement >>
selectionRectangles
	"return all selections rectangles from coordinate system of text elements with selection to my local coordinates"

	editorElement mode
		ifWithPrimarySelectionDo: [
			^ Array streamContents: [ :stream |
				  editorElement textElementsDo: [ :te |
					  te selectionRectangles do: [ :r |
						  stream nextPut: ((editorElement
								    localBoundsToMine: (BlBounds fromRectangle: r)
								    fromChild: te) translateBy: 0 @ te position y negated) ] ] ] ]
		ifNot: [ ^ #(  ) ]

[joao-pedro-braz]

From discussion on Discord, this issue also affects selecting text, particularly on large lines.

Profile:

Videos:

Screencast.From.2025-11-17.15-30-44.mp4

Screencast.From.2025-11-17.15-31-08.mp4

[tinchodias]

You are right, without the line breaks i.e. a large single line, is unusable. This needs a fix.

With a scroll bar (play with the lorem ipsum size):

editor := AlbEditorElement new.
editor text:( (String loremIpsum: 10000) reject: [ :each | each isLineBreak ]) asRopedText.

vscrollBar := BlVerticalScrollbarElement new.
vscrollBar constraintsDo: [ :c |
	c ignoreByLayout.
	c ignored horizontal alignRight ].
vscrollBar attachTo: editor infinite.

vscrollBar thumb
	addEventHandlerOn: BlDragStartEvent do: [ :evt |
		profiler := AndreasSystemProfiler new.
		profiler startProfiling ];
	addEventHandlerOn: BlDragEndEvent do: [ :evt |
		profiler stopProfiling.
		"profiler doReport"
		profiler saucoAsReport asFlameGraph open  ].

space := BlSpace new.
space root addChild: editor.
space root addChild: vscrollBar.
space extent: 300@900.
space show.

A more automatic script (back still lacks an output with metrics):

keyDelay := 0.05 second.
key := KeyboardKey right.
textSize := 1000.

editor := AlbEditorElement new.
editor text:
	((String loremIpsum: textSize) reject: [ :each | each isLineBreak ]) asRopedText.

space := BlSpace new.
space root addChild: editor.
space extent: 500 @ 500.
"space useMorphicHost."
space show.

"Ensure start with cursor at first character"
editor whenLayoutedDoOnce: [
	{ BlPrimaryMouseDownEvent. BlPrimaryMouseUpEvent } do: [ :each |
		space dispatchEventWithTimestamp:
			(each new
				position: editor boundsInSpace position;
				button: BlMouseButton primary;
				yourself) ] ].

"Shift+RIGHT until YOU close the space"
editor enqueueTask:
	(BlRepeatedTaskAction new
		delay: keyDelay;
		action: [
			modifiers := BlKeyModifiers
				shift: true
				ctrl: false
				alt: false
				cmd: false.
				
			{	BlKeyDownEvent new
					key: KeyboardKey shiftLeft;
					yourself.
				BlKeyDownEvent new
					key: key;
					yourself.
				BlKeyUpEvent new
					key: key;
					yourself.
				BlKeyUpEvent new
					key: KeyboardKey shiftLeft;
					yourself
			} do: [ :each |
				each modifiers: modifiers.
				space dispatchEventWithTimestamp: each ] ];
		yourself).

[tinchodias]

This is how the automation looks:

With a line with 10k characters, I get between 60% to 70% of the time consumed in recalculation of the selection polygon. This is the flame graph:

The script (requires https://github.com/tinchodias/Sauco):

keyDelay := 0.05 second.
key := KeyboardKey right.
textSize := 10000.

editor := AlbEditorElement new.
editor text:
	((String loremIpsum: textSize) reject: [ :each | each isLineBreak ]) asRopedText.

space := BlSpace new.
space root addChild: editor.
space extent: 500 @ 500.
space show.

space
	addEventHandlerOn: BlSpaceShownEvent
	do: [ :evt |
		profiler := AndreasSystemProfiler new.
		profiler startProfiling ].

"Ensure start with cursor at first character"
editor whenLayoutedDoOnce: [
	{ BlPrimaryMouseDownEvent. BlPrimaryMouseUpEvent } do: [ :each |
		space dispatchEventWithTimestamp:
			(each new
				position: editor boundsInSpace position;
				button: BlMouseButton primary;
				yourself) ] ].

"Shift+RIGHT until YOU close the space"
editor enqueueTask:
	(BlRepeatedTaskAction new
		delay: keyDelay;
		action: [
			modifiers := BlKeyModifiers
				shift: true
				ctrl: false
				alt: false
				cmd: false.
				
			{	BlKeyDownEvent new
					key: KeyboardKey shiftLeft;
					   yourself.
				BlKeyDownEvent new
					key: key;
					   yourself.
				BlKeyUpEvent new
					key: key;
					   yourself.
				BlKeyUpEvent new
					key: KeyboardKey shiftLeft;
					   yourself
			} do: [ :each |
				each modifiers: modifiers.
				space dispatchEventWithTimestamp: each ] ];
		yourself).

space
	addEventHandlerOn: BlSpaceClosedEvent
	do: [ :evt |
		| report |
		profiler stopProfiling.
		report := profiler saucoAsReport.
		report
			colorMap:
				(SaCategoryPrefixColorMap new 
					mapPrefixes: #(
						'OSWindow'
						'Alexandrie')
						from: Color lightBlue;
					mapPrefixes: #(
						'Bloc-Text'
						'BlocHost'
						'Bloc')
						from: Color orange;
					mapPrefixes: #(
						'Album'
						'Toplo')
						from: Color pink;
					yourself).
		report asFlameGraph open ]